src/rt/rayinit.cal

{ RCSid $Id: rayinit.cal,v 2.14 2003/03/11 19:29:05 greg Exp $ }
{
        Initialization file for Radiance.

        The following are predefined:

        Dx, Dy, Dz                      - ray direction
        Nx, Ny, Nz                      - surface normal
        Px, Py, Pz                      - intersection point
        T                               - distance from start
        Ts                              - single ray (shadow) distance
        Rdot                            - ray dot product
        S                               - world scale
        Tx, Ty, Tz                      - world origin
        Ix, Iy, Iz                      - world i unit vector
        Jx, Jy, Jz                      - world j unit vector
        Kx, Ky, Kz                      - world k unit vector
        arg(n)                          - real arguments, arg(0) is count

        For mesh objects, the following are available:

        Lu, Lv                          - local (u,v) coordinates

        For *func & *data materials, the following are also available:

        NxP, NyP, NzP                   - perturbed surface normal
        RdotP                           - perturbed ray dot product
        CrP, CgP, CbP                   - perturbed material color

        For prism1 and prism2 types, the following are available:

        DxA, DyA, DzA                   - direction to target light source

        Library functions:

        if(a, b, c)                     - if a positive, return b, else c

        select(N, a1, a2, ..)           - return aN

        sqrt(x)                         - square root function

        sin(x), cos(x), tan(x),
        asin(x), acos(x),
        atan(x), atan2(y,x)             - standard trig functions (radians)

        floor(x), ceil(x)               - g.l.b. & l.u.b.

        exp(x), log(x), log10(x)        - exponent and log functions

        erf(z), erfc(z)                 - error functions

        rand(x)                         - pseudo-random function (0 to 1)

        hermite(p0,p1,r0,r1,t)          - 1-dimensional hermite polynomial

        noise3(x,y,z), noise3x(x,y,z),
        noise3y(x,y,z), noise3z(x,y,z)  - noise function with gradient (-1 to 1)

        fnoise3(x,y,z)                  - fractal noise function (-1 to 1)
}

                        { Backward compatibility }
AC = arg(0);
A1 = arg(1); A2 = arg(2); A3 = arg(3); A4 = arg(4); A5 = arg(5);
A6 = arg(6); A7 = arg(7); A8 = arg(8); A9 = arg(9); A10 = arg(10);

noise3a(x,y,z) : noise3x(x,y,z);
noise3b(x,y,z) : noise3y(x,y,z);
noise3c(x,y,z) : noise3z(x,y,z);

                        { Forward compatibility (?) }
D(i) = select(i, Dx, Dy, Dz);
N(i) = select(i, Nx, Ny, Nz);
P(i) = select(i, Px, Py, Pz);
noise3d(i,x,y,z) : select(i, noise3x(x,y,z), noise3y(x,y,z), noise3z(x,y,z));

                        { More robust versions of library functions }
bound(a,x,b) : if(a-x, a, if(x-b, b, x));
Acos(x) : acos(bound(-1,x,1));
Asin(x) : asin(bound(-1,x,1));
Atan2(y,x) : if(x*x+y*y, atan2(y,x), 0);
Exp(x) : if(-x-100, 0, exp(x));
Sqrt(x) : if(x, sqrt(x), 0);

                        { Useful constants }
PI : 3.14159265358979323846;
DEGREE : PI/180;
FTINY : 1e-7;

                        { Useful functions }
and(a,b) : if( a, b, a );
or(a,b) : if( a, a, b );
not(a) : if( a, -1, 1 );
xor(a,b) : if( a, not(b), b );
abs(x) : if( x, x, -x );
sgn(x) : if( x, 1, if(-x, -1, 0) );
sq(x) : x*x;
max(a,b) : if( a-b, a, b );
min(a,b) : if( a-b, b, a );
inside(a,x,b) : and(x-a,b-x);
frac(x) : x - floor(x);
mod(n,d) : n - floor(n/d)*d;
tri(n,d) : abs( d - mod(n-d,2*d) );
linterp(t,p0,p1) : (1-t)*p0 + t*p1;

noop(v) : v;
clip(v) : bound(0,v,1);
noneg(v) : if(v,v,0);
red(r,g,b) : if(r,r,0);
green(r,g,b) : if(g,g,0);
blue(r,g,b) : if(b,b,0);
grey(r,g,b) : noneg(.265074126*r + .670114631*g + .064811243*b);
clip_r(r,g,b) : bound(0,r,1);
clip_g(r,g,b) : bound(0,g,1);
clip_b(r,g,b) : bound(0,b,1);
clipgrey(r,g,b) : min(grey(r,g,b),1);

dot(v1,v2) : v1(1)*v2(1) + v1(2)*v2(2) + v1(3)*v2(3);
cross(i,v1,v2) : select(i,      v1(2)*v2(3) - v1(3)*v2(2),
                                v1(3)*v2(1) - v1(1)*v2(3),
                                v1(1)*v2(2) - v1(2)*v2(1));

fade(near_val,far_val,dist) : far_val +
                if (16-dist, (near_val-far_val)/(1+dist*dist), 0);

bezier(p1, p2, p3, p4, t) :     p1 * (1+t*(-3+t*(3-t))) +
                                p2 * 3*t*(1+t*(-2+t)) +
                                p3 * 3*t*t*(1-t) +
                                p4 * t*t*t ;

bspline(pp, p0, p1, pn, t) :    pp * (1/6+t*(-.5+t*(.5-1/6*t))) +
                                p0 * (2/3+t*t*(-1+.5*t)) +
                                p1 * (1/6+t*(.5+t*(.5-.5*t))) +
                                pn * (1/6*t*t*t) ;

turbulence(x,y,z,s) : if( s-1.01, 0, abs(noise3(x/s,y/s,z/s)*s) +
                                                turbulence(x,y,z,2*s) );
turbulencex(x,y,z,s) : if( s-1.01, 0,
                        sgn(noise3(x/s,y/s,z/s))*noise3x(x/s,y/s,z/s) +
                        turbulencex(x,y,z,2*s) );
turbulencey(x,y,z,s) : if( s-1.01, 0,
                        sgn(noise3(x/s,y/s,z/s))*noise3y(x/s,y/s,z/s) +
                        turbulencey(x,y,z,2*s) );
turbulencez(x,y,z,s) : if( s-1.01, 0,
                        sgn(noise3(x/s,y/s,z/s))*noise3z(x/s,y/s,z/s) +
                        turbulencez(x,y,z,2*s) );

                        { Normal distribution from uniform range (0,1) }

un2`P(t) : t - (2.515517+t*(.802853+t*.010328))/
                (1+t*(1.432788+t*(.189269+t*.001308))) ;
un1`P(p) : un2`P(sqrt(-2*log(p))) ;

unif2norm(p) : if( .5-p, -un1`P(p), un1`P(1-p) ) ;

nrand(x) = unif2norm(rand(x));

                        { Local (u,v) coordinates for planar surfaces }
crosslen`P = Nx*Nx + Ny*Ny;
                        { U is distance from projected Z-axis }
U = if( crosslen`P - FTINY,
                (Py*Nx - Px*Ny)/crosslen`P,
                Px);
                        { V is defined so that N = U x V }
V = if( crosslen`P - FTINY,
                Pz - Nz*(Px*Nx + Py*Ny)/crosslen`P,
                Py);
Revision:	2.15
Committed:	Mon Mar 25 16:10:00 2013 UTC (11 years, 1 month ago) by greg
Branch:	MAIN
Changes since 2.14:	+3 -3 lines
Log Message:	Improved some comments as suggested by PAB
#	User	Rev	Content
1	greg	2.15	{ RCSid $Id: rayinit.cal,v 2.14 2003/03/11 19:29:05 greg Exp $ }
2	greg	1.1	{
3			Initialization file for Radiance.
4
5			The following are predefined:
6
7			Dx, Dy, Dz - ray direction
8			Nx, Ny, Nz - surface normal
9			Px, Py, Pz - intersection point
10			T - distance from start
11	greg	2.3	Ts - single ray (shadow) distance
12	greg	1.1	Rdot - ray dot product
13			S - world scale
14			Tx, Ty, Tz - world origin
15			Ix, Iy, Iz - world i unit vector
16			Jx, Jy, Jz - world j unit vector
17			Kx, Ky, Kz - world k unit vector
18			arg(n) - real arguments, arg(0) is count
19	greg	2.14
20			For mesh objects, the following are available:
21
22			Lu, Lv - local (u,v) coordinates
23	greg	1.1
24	greg	2.15	For func & data materials, the following are also available:
25	greg	1.1
26			NxP, NyP, NzP - perturbed surface normal
27			RdotP - perturbed ray dot product
28			CrP, CgP, CbP - perturbed material color
29
30	greg	2.9	For prism1 and prism2 types, the following are available:
31
32			DxA, DyA, DzA - direction to target light source
33
34	greg	1.1	Library functions:
35
36			if(a, b, c) - if a positive, return b, else c
37
38			select(N, a1, a2, ..) - return aN
39
40			sqrt(x) - square root function
41
42			sin(x), cos(x), tan(x),
43			asin(x), acos(x),
44	greg	2.15	atan(x), atan2(y,x) - standard trig functions (radians)
45	greg	1.1
46			floor(x), ceil(x) - g.l.b. & l.u.b.
47
48			exp(x), log(x), log10(x) - exponent and log functions
49
50			erf(z), erfc(z) - error functions
51
52			rand(x) - pseudo-random function (0 to 1)
53
54			hermite(p0,p1,r0,r1,t) - 1-dimensional hermite polynomial
55
56	greg	2.11	noise3(x,y,z), noise3x(x,y,z),
57			noise3y(x,y,z), noise3z(x,y,z) - noise function with gradient (-1 to 1)
58	greg	1.1
59			fnoise3(x,y,z) - fractal noise function (-1 to 1)
60			}
61
62			{ Backward compatibility }
63			AC = arg(0);
64			A1 = arg(1); A2 = arg(2); A3 = arg(3); A4 = arg(4); A5 = arg(5);
65			A6 = arg(6); A7 = arg(7); A8 = arg(8); A9 = arg(9); A10 = arg(10);
66
67	greg	2.11	noise3a(x,y,z) : noise3x(x,y,z);
68			noise3b(x,y,z) : noise3y(x,y,z);
69			noise3c(x,y,z) : noise3z(x,y,z);
70
71	greg	1.1	{ Forward compatibility (?) }
72			D(i) = select(i, Dx, Dy, Dz);
73			N(i) = select(i, Nx, Ny, Nz);
74			P(i) = select(i, Px, Py, Pz);
75	greg	2.11	noise3d(i,x,y,z) : select(i, noise3x(x,y,z), noise3y(x,y,z), noise3z(x,y,z));
76	greg	1.1
77			{ More robust versions of library functions }
78			bound(a,x,b) : if(a-x, a, if(x-b, b, x));
79			Acos(x) : acos(bound(-1,x,1));
80			Asin(x) : asin(bound(-1,x,1));
81	greg	2.8	Atan2(y,x) : if(xx+yy, atan2(y,x), 0);
82	greg	2.2	Exp(x) : if(-x-100, 0, exp(x));
83	greg	1.1	Sqrt(x) : if(x, sqrt(x), 0);
84
85			{ Useful constants }
86			PI : 3.14159265358979323846;
87			DEGREE : PI/180;
88			FTINY : 1e-7;
89
90			{ Useful functions }
91			and(a,b) : if( a, b, a );
92			or(a,b) : if( a, a, b );
93			not(a) : if( a, -1, 1 );
94	greg	2.13	xor(a,b) : if( a, not(b), b );
95	greg	1.1	abs(x) : if( x, x, -x );
96			sgn(x) : if( x, 1, if(-x, -1, 0) );
97			sq(x) : x*x;
98			max(a,b) : if( a-b, a, b );
99			min(a,b) : if( a-b, b, a );
100			inside(a,x,b) : and(x-a,b-x);
101			frac(x) : x - floor(x);
102			mod(n,d) : n - floor(n/d)*d;
103			tri(n,d) : abs( d - mod(n-d,2*d) );
104			linterp(t,p0,p1) : (1-t)p0 + tp1;
105
106	gwlarson	2.12	noop(v) : v;
107			clip(v) : bound(0,v,1);
108			noneg(v) : if(v,v,0);
109			red(r,g,b) : if(r,r,0);
110			green(r,g,b) : if(g,g,0);
111			blue(r,g,b) : if(b,b,0);
112			grey(r,g,b) : noneg(.265074126r + .670114631g + .064811243*b);
113			clip_r(r,g,b) : bound(0,r,1);
114			clip_g(r,g,b) : bound(0,g,1);
115			clip_b(r,g,b) : bound(0,b,1);
116			clipgrey(r,g,b) : min(grey(r,g,b),1);
117	greg	1.1
118			dot(v1,v2) : v1(1)v2(1) + v1(2)v2(2) + v1(3)*v2(3);
119			cross(i,v1,v2) : select(i, v1(2)v2(3) - v1(3)v2(2),
120			v1(3)v2(1) - v1(1)v2(3),
121			v1(1)v2(2) - v1(2)v2(1));
122
123	gwlarson	2.12	fade(near_val,far_val,dist) : far_val +
124	greg	1.1	if (16-dist, (near_val-far_val)/(1+dist*dist), 0);
125
126	gwlarson	2.12	bezier(p1, p2, p3, p4, t) : p1 * (1+t(-3+t(3-t))) +
127	greg	1.1	p2 * 3t(1+t*(-2+t)) +
128			p3 * 3tt*(1-t) +
129			p4 * ttt ;
130
131	gwlarson	2.12	bspline(pp, p0, p1, pn, t) : pp * (1/6+t(-.5+t(.5-1/6*t))) +
132	greg	1.1	p0 * (2/3+tt(-1+.5*t)) +
133			p1 * (1/6+t(.5+t(.5-.5*t))) +
134			pn * (1/6tt*t) ;
135
136	gwlarson	2.12	turbulence(x,y,z,s) : if( s-1.01, 0, abs(noise3(x/s,y/s,z/s)*s) +
137	greg	1.1	turbulence(x,y,z,2*s) );
138	gwlarson	2.12	turbulencex(x,y,z,s) : if( s-1.01, 0,
139	greg	2.11	sgn(noise3(x/s,y/s,z/s))*noise3x(x/s,y/s,z/s) +
140	gwlarson	2.12	turbulencex(x,y,z,2*s) );
141			turbulencey(x,y,z,s) : if( s-1.01, 0,
142	greg	2.11	sgn(noise3(x/s,y/s,z/s))*noise3y(x/s,y/s,z/s) +
143	gwlarson	2.12	turbulencey(x,y,z,2*s) );
144			turbulencez(x,y,z,s) : if( s-1.01, 0,
145	greg	2.11	sgn(noise3(x/s,y/s,z/s))*noise3z(x/s,y/s,z/s) +
146	gwlarson	2.12	turbulencez(x,y,z,2*s) );
147	greg	1.2
148	greg	1.3	{ Normal distribution from uniform range (0,1) }
149
150	gwlarson	2.12	un2`P(t) : t - (2.515517+t(.802853+t.010328))/
151	greg	1.3	(1+t(1.432788+t(.189269+t*.001308))) ;
152	gwlarson	2.12	un1`P(p) : un2`P(sqrt(-2*log(p))) ;
153	greg	1.3
154	gwlarson	2.12	unif2norm(p) : if( .5-p, -un1`P(p), un1`P(1-p) ) ;
155	greg	1.3
156			nrand(x) = unif2norm(rand(x));
157
158	greg	1.2	{ Local (u,v) coordinates for planar surfaces }
159	gwlarson	2.12	crosslen`P = NxNx + NyNy;
160	greg	2.7	{ U is distance from projected Z-axis }
161	gwlarson	2.12	U = if( crosslen`P - FTINY,
162			(PyNx - PxNy)/crosslen`P,
163	greg	1.2	Px);
164			{ V is defined so that N = U x V }
165	gwlarson	2.12	V = if( crosslen`P - FTINY,
166			Pz - Nz(PxNx + Py*Ny)/crosslen`P,
167	greg	1.2	Py);