src/rt/rayinit.cal

{ RCSid $Id: rayinit.cal,v 2.16 2013/10/08 18:59:44 greg Exp $ }
{
        Initialization file for Radiance.

        The following are predefined:

        Dx, Dy, Dz                      - ray direction
        Nx, Ny, Nz                      - surface normal
        Px, Py, Pz                      - intersection point
        T                               - distance from start
        Ts                              - single ray (shadow) distance
        Rdot                            - ray dot product
        S                               - world scale
        Tx, Ty, Tz                      - world origin
        Ix, Iy, Iz                      - world i unit vector
        Jx, Jy, Jz                      - world j unit vector
        Kx, Ky, Kz                      - world k unit vector
        arg(n)                          - real arguments, arg(0) is count

        For mesh objects, the following are available:

        Lu, Lv                          - local (u,v) coordinates

        For *func & *data materials, the following are also available:

        NxP, NyP, NzP                   - perturbed surface normal
        RdotP                           - perturbed ray dot product
        CrP, CgP, CbP                   - perturbed material color

        For prism1 and prism2 types, the following are available:

        DxA, DyA, DzA                   - direction to target light source

        Library functions:

        if(a, b, c)                     - if a positive, return b, else c

        select(N, a1, a2, ..)           - return aN

        sqrt(x)                         - square root function

        sin(x), cos(x), tan(x),
        asin(x), acos(x),
        atan(x), atan2(y,x)             - standard trig functions (radians)

        floor(x), ceil(x)               - g.l.b. & l.u.b.

        exp(x), log(x), log10(x)        - exponent and log functions

        erf(z), erfc(z)                 - error functions

        rand(x)                         - pseudo-random function (0 to 1)

        noise3(x,y,z), noise3x(x,y,z),
        noise3y(x,y,z), noise3z(x,y,z)  - noise function with gradient (-1 to 1)

        fnoise3(x,y,z)                  - fractal noise function (-1 to 1)
}

                        { Backward compatibility }
AC = arg(0);
A1 = arg(1); A2 = arg(2); A3 = arg(3); A4 = arg(4); A5 = arg(5);
A6 = arg(6); A7 = arg(7); A8 = arg(8); A9 = arg(9); A10 = arg(10);

noise3a(x,y,z) : noise3x(x,y,z);
noise3b(x,y,z) : noise3y(x,y,z);
noise3c(x,y,z) : noise3z(x,y,z);

                        { Forward compatibility (?) }
D(i) = select(i, Dx, Dy, Dz);
N(i) = select(i, Nx, Ny, Nz);
P(i) = select(i, Px, Py, Pz);
noise3d(i,x,y,z) : select(i, noise3x(x,y,z), noise3y(x,y,z), noise3z(x,y,z));

                        { More robust versions of library functions }
bound(a,x,b) : if(a-x, a, if(x-b, b, x));
Acos(x) : acos(bound(-1,x,1));
Asin(x) : asin(bound(-1,x,1));
Atan2(y,x) : if(x*x+y*y, atan2(y,x), 0);
Exp(x) : if(-x-100, 0, exp(x));
Sqrt(x) : if(x, sqrt(x), 0);

                        { Useful constants }
PI : 3.14159265358979323846;
DEGREE : PI/180;
FTINY : 1e-7;

                        { Useful functions }
and(a,b) : if( a, b, a );
or(a,b) : if( a, a, b );
not(a) : if( a, -1, 1 );
xor(a,b) : if( a, not(b), b );
abs(x) : if( x, x, -x );
sgn(x) : if( x, 1, if(-x, -1, 0) );
sq(x) : x*x;
max(a,b) : if( a-b, a, b );
min(a,b) : if( a-b, b, a );
inside(a,x,b) : and(x-a,b-x);
frac(x) : x - floor(x);
mod(n,d) : n - floor(n/d)*d;
tri(n,d) : abs( d - mod(n-d,2*d) );
linterp(t,p0,p1) : (1-t)*p0 + t*p1;

noop(v) : v;
clip(v) : bound(0,v,1);
noneg(v) : if(v,v,0);
red(r,g,b) : if(r,r,0);
green(r,g,b) : if(g,g,0);
blue(r,g,b) : if(b,b,0);
grey(r,g,b) : noneg(.265074126*r + .670114631*g + .064811243*b);
clip_r(r,g,b) : bound(0,r,1);
clip_g(r,g,b) : bound(0,g,1);
clip_b(r,g,b) : bound(0,b,1);
clipgrey(r,g,b) : min(grey(r,g,b),1);

dot(v1,v2) : v1(1)*v2(1) + v1(2)*v2(2) + v1(3)*v2(3);
cross(i,v1,v2) : select(i,      v1(2)*v2(3) - v1(3)*v2(2),
                                v1(3)*v2(1) - v1(1)*v2(3),
                                v1(1)*v2(2) - v1(2)*v2(1));

fade(near_val,far_val,dist) : far_val +
                if (16-dist, (near_val-far_val)/(1+dist*dist), 0);

hermite(p0,p1,r0,r1,t) :        p0 * ((2*t-3)*t*t+1) +
                                p1 * (-2*t+3)*t*t +
                                r0 * (((t-2)*t+1)*t) +
                                r1 * ((t-1)*t*t);

bezier(p1, p2, p3, p4, t) :     p1 * (1+t*(-3+t*(3-t))) +
                                p2 * 3*t*(1+t*(-2+t)) +
                                p3 * 3*t*t*(1-t) +
                                p4 * t*t*t ;

bspline(pp, p0, p1, pn, t) :    pp * (1/6+t*(-.5+t*(.5-1/6*t))) +
                                p0 * (2/3+t*t*(-1+.5*t)) +
                                p1 * (1/6+t*(.5+t*(.5-.5*t))) +
                                pn * (1/6*t*t*t) ;

turbulence(x,y,z,s) : if( s-1.01, 0, abs(noise3(x/s,y/s,z/s)*s) +
                                                turbulence(x,y,z,2*s) );
turbulencex(x,y,z,s) : if( s-1.01, 0,
                        sgn(noise3(x/s,y/s,z/s))*noise3x(x/s,y/s,z/s) +
                        turbulencex(x,y,z,2*s) );
turbulencey(x,y,z,s) : if( s-1.01, 0,
                        sgn(noise3(x/s,y/s,z/s))*noise3y(x/s,y/s,z/s) +
                        turbulencey(x,y,z,2*s) );
turbulencez(x,y,z,s) : if( s-1.01, 0,
                        sgn(noise3(x/s,y/s,z/s))*noise3z(x/s,y/s,z/s) +
                        turbulencez(x,y,z,2*s) );

                        { Normal distribution from uniform range (0,1) }

un2`P.(t) : t - (2.515517+t*(.802853+t*.010328))/
                (1+t*(1.432788+t*(.189269+t*.001308))) ;
un1`P.(p) : un2`P.(sqrt(-2*log(p))) ;

unif2norm(p) : if( .5-p, -un1`P.(p), un1`P.(1-p) ) ;

nrand(x) = unif2norm(rand(x));

                        { Local (u,v) coordinates for planar surfaces }
crosslen`P. = Nx*Nx + Ny*Ny;
                        { U is distance from projected Z-axis }
U = if( crosslen`P. - FTINY,
                (Py*Nx - Px*Ny)/crosslen`P.,
                Px);
                        { V is defined so that N = U x V }
V = if( crosslen`P. - FTINY,
                Pz - Nz*(Px*Nx + Py*Ny)/crosslen`P.,
                Py);
Revision:	2.17
Committed:	Thu Jan 18 19:43:43 2018 UTC (7 years, 9 months ago) by greg
Branch:	MAIN
CVS Tags:	rad5R2
Changes since 2.16:	+9 -9 lines
Log Message:	Changed context names to avoid collision with user-specified .cal file names
#	User	Rev	Content
1	greg	2.17	{ RCSid $Id: rayinit.cal,v 2.16 2013/10/08 18:59:44 greg Exp $ }
2	greg	1.1	{
3			Initialization file for Radiance.
4
5			The following are predefined:
6
7			Dx, Dy, Dz - ray direction
8			Nx, Ny, Nz - surface normal
9			Px, Py, Pz - intersection point
10			T - distance from start
11	greg	2.3	Ts - single ray (shadow) distance
12	greg	1.1	Rdot - ray dot product
13			S - world scale
14			Tx, Ty, Tz - world origin
15			Ix, Iy, Iz - world i unit vector
16			Jx, Jy, Jz - world j unit vector
17			Kx, Ky, Kz - world k unit vector
18			arg(n) - real arguments, arg(0) is count
19	greg	2.14
20			For mesh objects, the following are available:
21
22			Lu, Lv - local (u,v) coordinates
23	greg	1.1
24	greg	2.15	For func & data materials, the following are also available:
25	greg	1.1
26			NxP, NyP, NzP - perturbed surface normal
27			RdotP - perturbed ray dot product
28			CrP, CgP, CbP - perturbed material color
29
30	greg	2.9	For prism1 and prism2 types, the following are available:
31
32			DxA, DyA, DzA - direction to target light source
33
34	greg	1.1	Library functions:
35
36			if(a, b, c) - if a positive, return b, else c
37
38			select(N, a1, a2, ..) - return aN
39
40			sqrt(x) - square root function
41
42			sin(x), cos(x), tan(x),
43			asin(x), acos(x),
44	greg	2.15	atan(x), atan2(y,x) - standard trig functions (radians)
45	greg	1.1
46			floor(x), ceil(x) - g.l.b. & l.u.b.
47
48			exp(x), log(x), log10(x) - exponent and log functions
49
50			erf(z), erfc(z) - error functions
51
52			rand(x) - pseudo-random function (0 to 1)
53
54	greg	2.11	noise3(x,y,z), noise3x(x,y,z),
55			noise3y(x,y,z), noise3z(x,y,z) - noise function with gradient (-1 to 1)
56	greg	1.1
57			fnoise3(x,y,z) - fractal noise function (-1 to 1)
58			}
59
60			{ Backward compatibility }
61			AC = arg(0);
62			A1 = arg(1); A2 = arg(2); A3 = arg(3); A4 = arg(4); A5 = arg(5);
63			A6 = arg(6); A7 = arg(7); A8 = arg(8); A9 = arg(9); A10 = arg(10);
64
65	greg	2.11	noise3a(x,y,z) : noise3x(x,y,z);
66			noise3b(x,y,z) : noise3y(x,y,z);
67			noise3c(x,y,z) : noise3z(x,y,z);
68
69	greg	1.1	{ Forward compatibility (?) }
70			D(i) = select(i, Dx, Dy, Dz);
71			N(i) = select(i, Nx, Ny, Nz);
72			P(i) = select(i, Px, Py, Pz);
73	greg	2.11	noise3d(i,x,y,z) : select(i, noise3x(x,y,z), noise3y(x,y,z), noise3z(x,y,z));
74	greg	1.1
75			{ More robust versions of library functions }
76			bound(a,x,b) : if(a-x, a, if(x-b, b, x));
77			Acos(x) : acos(bound(-1,x,1));
78			Asin(x) : asin(bound(-1,x,1));
79	greg	2.8	Atan2(y,x) : if(xx+yy, atan2(y,x), 0);
80	greg	2.2	Exp(x) : if(-x-100, 0, exp(x));
81	greg	1.1	Sqrt(x) : if(x, sqrt(x), 0);
82
83			{ Useful constants }
84			PI : 3.14159265358979323846;
85			DEGREE : PI/180;
86			FTINY : 1e-7;
87
88			{ Useful functions }
89			and(a,b) : if( a, b, a );
90			or(a,b) : if( a, a, b );
91			not(a) : if( a, -1, 1 );
92	greg	2.13	xor(a,b) : if( a, not(b), b );
93	greg	1.1	abs(x) : if( x, x, -x );
94			sgn(x) : if( x, 1, if(-x, -1, 0) );
95			sq(x) : x*x;
96			max(a,b) : if( a-b, a, b );
97			min(a,b) : if( a-b, b, a );
98			inside(a,x,b) : and(x-a,b-x);
99			frac(x) : x - floor(x);
100			mod(n,d) : n - floor(n/d)*d;
101			tri(n,d) : abs( d - mod(n-d,2*d) );
102			linterp(t,p0,p1) : (1-t)p0 + tp1;
103
104	gwlarson	2.12	noop(v) : v;
105			clip(v) : bound(0,v,1);
106			noneg(v) : if(v,v,0);
107			red(r,g,b) : if(r,r,0);
108			green(r,g,b) : if(g,g,0);
109			blue(r,g,b) : if(b,b,0);
110			grey(r,g,b) : noneg(.265074126r + .670114631g + .064811243*b);
111			clip_r(r,g,b) : bound(0,r,1);
112			clip_g(r,g,b) : bound(0,g,1);
113			clip_b(r,g,b) : bound(0,b,1);
114			clipgrey(r,g,b) : min(grey(r,g,b),1);
115	greg	1.1
116			dot(v1,v2) : v1(1)v2(1) + v1(2)v2(2) + v1(3)*v2(3);
117			cross(i,v1,v2) : select(i, v1(2)v2(3) - v1(3)v2(2),
118			v1(3)v2(1) - v1(1)v2(3),
119			v1(1)v2(2) - v1(2)v2(1));
120
121	gwlarson	2.12	fade(near_val,far_val,dist) : far_val +
122	greg	1.1	if (16-dist, (near_val-far_val)/(1+dist*dist), 0);
123
124	greg	2.16	hermite(p0,p1,r0,r1,t) : p0 * ((2t-3)t*t+1) +
125			p1 * (-2t+3)t*t +
126			r0 * (((t-2)t+1)t) +
127			r1 * ((t-1)tt);
128
129	gwlarson	2.12	bezier(p1, p2, p3, p4, t) : p1 * (1+t(-3+t(3-t))) +
130	greg	1.1	p2 * 3t(1+t*(-2+t)) +
131			p3 * 3tt*(1-t) +
132			p4 * ttt ;
133
134	gwlarson	2.12	bspline(pp, p0, p1, pn, t) : pp * (1/6+t(-.5+t(.5-1/6*t))) +
135	greg	1.1	p0 * (2/3+tt(-1+.5*t)) +
136			p1 * (1/6+t(.5+t(.5-.5*t))) +
137			pn * (1/6tt*t) ;
138
139	gwlarson	2.12	turbulence(x,y,z,s) : if( s-1.01, 0, abs(noise3(x/s,y/s,z/s)*s) +
140	greg	1.1	turbulence(x,y,z,2*s) );
141	gwlarson	2.12	turbulencex(x,y,z,s) : if( s-1.01, 0,
142	greg	2.11	sgn(noise3(x/s,y/s,z/s))*noise3x(x/s,y/s,z/s) +
143	gwlarson	2.12	turbulencex(x,y,z,2*s) );
144			turbulencey(x,y,z,s) : if( s-1.01, 0,
145	greg	2.11	sgn(noise3(x/s,y/s,z/s))*noise3y(x/s,y/s,z/s) +
146	gwlarson	2.12	turbulencey(x,y,z,2*s) );
147			turbulencez(x,y,z,s) : if( s-1.01, 0,
148	greg	2.11	sgn(noise3(x/s,y/s,z/s))*noise3z(x/s,y/s,z/s) +
149	gwlarson	2.12	turbulencez(x,y,z,2*s) );
150	greg	1.2
151	greg	1.3	{ Normal distribution from uniform range (0,1) }
152
153	greg	2.17	un2`P.(t) : t - (2.515517+t(.802853+t.010328))/
154	greg	1.3	(1+t(1.432788+t(.189269+t*.001308))) ;
155	greg	2.17	un1`P.(p) : un2`P.(sqrt(-2*log(p))) ;
156	greg	1.3
157	greg	2.17	unif2norm(p) : if( .5-p, -un1`P.(p), un1`P.(1-p) ) ;
158	greg	1.3
159			nrand(x) = unif2norm(rand(x));
160
161	greg	1.2	{ Local (u,v) coordinates for planar surfaces }
162	greg	2.17	crosslen`P. = NxNx + NyNy;
163	greg	2.7	{ U is distance from projected Z-axis }
164	greg	2.17	U = if( crosslen`P. - FTINY,
165			(PyNx - PxNy)/crosslen`P.,
166	greg	1.2	Px);
167			{ V is defined so that N = U x V }
168	greg	2.17	V = if( crosslen`P. - FTINY,
169			Pz - Nz(PxNx + Py*Ny)/crosslen`P.,
170	greg	1.2	Py);