| 1 |
#!/usr/bin/perl -w |
| 2 |
# RCSid $Id: rtpict.pl,v 2.26 2023/01/24 21:54:49 greg Exp $ |
| 3 |
# |
| 4 |
# Run rtrace in parallel mode to simulate rpict -n option |
| 5 |
# May also be used to render layered images with -o* option |
| 6 |
# |
| 7 |
# G. Ward |
| 8 |
# |
| 9 |
use strict; |
| 10 |
# we'll run rpict if no -n or -o* option |
| 11 |
my $nprocs = 1; |
| 12 |
# rtrace options and the associated number of arguments |
| 13 |
my %rtraceC = ('-dt',1, '-dc',1, '-dj',1, '-ds',1, '-dr',1, '-dp',1, |
| 14 |
'-ss',1, '-st',1, '-e',1, '-am',1, '-P',1, '-PP',1, |
| 15 |
'-ab',1, '-af',1, '-ai',1, '-aI',1, '-ae',1, '-aE',1, |
| 16 |
'-av',3, '-aw',1, '-aa',1, '-ar',1, '-ad',1, '-as',1, |
| 17 |
'-me',3, '-ma',3, '-mg',1, '-ms',1, '-lr',1, '-lw',1, |
| 18 |
'-ap',2, '-am',1, '-ac',1, '-aC',1, |
| 19 |
'-cs',1, '-cw',2, '-pc',8, '-pRGB',0, '-pXYZ',0); |
| 20 |
# boolean rtrace options |
| 21 |
my @boolO = ('-w', '-bv', '-dv', '-i', '-u'); |
| 22 |
# view options and the associated number of arguments |
| 23 |
my %vwraysC = ('-vf',1, '-vtv',0, '-vtl',0, '-vth',0, '-vta',0, '-vts',0, '-vtc',0, |
| 24 |
'-x',1, '-y',1, '-vp',3, '-vd',3, '-vu',3, '-vh',1, '-vv',1, |
| 25 |
'-vo',1, '-va',1, '-vs',1, '-vl',1, '-pa',1, '-pj',1, '-pd',1); |
| 26 |
# options we need to silently ignore |
| 27 |
my %ignoreC = ('-t',1, '-ps',1, '-pt',1, '-pm',1,); |
| 28 |
# Starting options for rtrace (rpict values) |
| 29 |
my @rtraceA = split(' ', 'rtrace -u- -dt .05 -dc .5 -ds .25 -dr 1 ' . |
| 30 |
'-aa .2 -ar 64 -ad 512 -as 128 -lr 7 -lw 1e-04'); |
| 31 |
my @vwraysA = ('vwrays', '-pj', '.67'); |
| 32 |
my @vwrightA = ('vwright', '-vtv'); |
| 33 |
my @rpictA = ('rpict', '-ps', '1'); |
| 34 |
my $outpatt = '^-o[vrxlLRXnNsmM]+'; |
| 35 |
my $refDepth = ""; |
| 36 |
my $irrad = 0; |
| 37 |
my $persist = 0; |
| 38 |
my $ambounce = 0; |
| 39 |
my $ambcache = 1; |
| 40 |
my $ambfile; |
| 41 |
my $outlyr; |
| 42 |
my $outdir; |
| 43 |
my $outpic; |
| 44 |
my $outzbf; |
| 45 |
OPTION: # sort through options |
| 46 |
while ($#ARGV >= 0 && "$ARGV[0]" =~ /^[-\@]/) { |
| 47 |
# Check for file inclusion |
| 48 |
if ("$ARGV[0]" =~ /^\@/) { |
| 49 |
open my $handle, '<', substr($ARGV[0], 1) or die "No file for $ARGV[0]\n"; |
| 50 |
shift @ARGV; |
| 51 |
chomp(my @args = <$handle>); |
| 52 |
close $handle; |
| 53 |
unshift @ARGV, split(/\s+/, "@args"); |
| 54 |
next OPTION; |
| 55 |
} |
| 56 |
# Check booleans |
| 57 |
for my $boopt (@boolO) { |
| 58 |
if ("$ARGV[0]" =~ ('^' . $boopt . '[-+01tfynTFYN]?$')) { |
| 59 |
if ("$ARGV[0]" eq '-i') { |
| 60 |
$irrad = ! $irrad; |
| 61 |
} elsif ("$ARGV[0]" =~ /^-i[-+01tfynTFYN]/) { |
| 62 |
$irrad = ("$ARGV[0]" =~ /^-i[+1tyTY]/); |
| 63 |
} |
| 64 |
push @rtraceA, $ARGV[0]; |
| 65 |
push @rpictA, shift(@ARGV); |
| 66 |
next OPTION; |
| 67 |
} |
| 68 |
} |
| 69 |
# Check view options |
| 70 |
if (defined $vwraysC{$ARGV[0]}) { |
| 71 |
push @vwraysA, $ARGV[0]; |
| 72 |
my $isvopt = ("$ARGV[0]" =~ /^-v/); |
| 73 |
push(@vwrightA, $ARGV[0]) if ($isvopt); |
| 74 |
push @rpictA, shift(@ARGV); |
| 75 |
for (my $i = $vwraysC{$rpictA[-1]}; $i-- > 0; ) { |
| 76 |
push @vwraysA, $ARGV[0]; |
| 77 |
push(@vwrightA, $ARGV[0]) if ($isvopt); |
| 78 |
push @rpictA, shift(@ARGV); |
| 79 |
} |
| 80 |
next OPTION; |
| 81 |
} |
| 82 |
# Check rtrace options |
| 83 |
if (defined $rtraceC{$ARGV[0]}) { |
| 84 |
if ("$ARGV[0]" =~ /^-PP?$/) { |
| 85 |
$persist = 1; |
| 86 |
} elsif ("$ARGV[0]" eq '-ab') { |
| 87 |
$ambounce = $ARGV[1]; |
| 88 |
} elsif ("$ARGV[0]" eq '-aa') { |
| 89 |
$ambcache = ($ARGV[1] > 0.0); |
| 90 |
} elsif ("$ARGV[0]" eq '-af') { |
| 91 |
$ambfile = "$ARGV[1]"; |
| 92 |
} |
| 93 |
push @rtraceA, $ARGV[0]; |
| 94 |
push @rpictA, shift(@ARGV); |
| 95 |
for (my $i = $rtraceC{$rpictA[-1]}; $i-- > 0; ) { |
| 96 |
push @rtraceA, $ARGV[0]; |
| 97 |
push @rpictA, shift(@ARGV); |
| 98 |
} |
| 99 |
next OPTION; |
| 100 |
} |
| 101 |
# Check options to ignore |
| 102 |
if (defined $ignoreC{$ARGV[0]}) { |
| 103 |
push @rpictA, shift(@ARGV); |
| 104 |
for (my $i = $ignoreC{$rpictA[-1]}; $i-- > 0; ) { |
| 105 |
push @rpictA, shift(@ARGV); |
| 106 |
} |
| 107 |
next OPTION; |
| 108 |
} |
| 109 |
# Check for output file or number of processes |
| 110 |
if ("$ARGV[0]" eq '-o') { |
| 111 |
shift @ARGV; |
| 112 |
$outpic = shift(@ARGV); |
| 113 |
} elsif ("$ARGV[0]" eq '-z') { |
| 114 |
push @rpictA, shift(@ARGV); |
| 115 |
$outzbf = $ARGV[0]; |
| 116 |
push @rpictA, shift(@ARGV); |
| 117 |
} elsif ("$ARGV[0]" eq '-n') { |
| 118 |
shift @ARGV; |
| 119 |
$nprocs = shift(@ARGV); |
| 120 |
} elsif ("$ARGV[0]" eq '-d') { |
| 121 |
shift @ARGV; |
| 122 |
$refDepth = ' -d ' . shift(@ARGV); |
| 123 |
} elsif ("$ARGV[0]" =~ "$outpatt") { |
| 124 |
push @rtraceA, $ARGV[0]; |
| 125 |
$outlyr = substr(shift(@ARGV), 2); |
| 126 |
$outdir = shift(@ARGV); |
| 127 |
} else { |
| 128 |
die "Unsupported option: " . $ARGV[0] . "\n"; |
| 129 |
} |
| 130 |
} |
| 131 |
die "Number of processes must be positive" if ($nprocs <= 0); |
| 132 |
if (defined $outdir) { # check conflicting options |
| 133 |
die "Options -o and -o* are mutually exclusive\n" if (defined $outpic); |
| 134 |
die "Options -z and -o* are mutually exclusive\n" if (defined $outzbf); |
| 135 |
} |
| 136 |
if (defined $outpic) { # redirect output? |
| 137 |
die "File '$outpic' already exists\n" if (-e $outpic); |
| 138 |
open STDOUT, '>', "$outpic"; |
| 139 |
} |
| 140 |
##################################################################### |
| 141 |
##### May as well run rpict? |
| 142 |
if ($nprocs == 1 && $persist == 0 && !defined($outdir)) { |
| 143 |
push(@rpictA, $ARGV[0]) if ($#ARGV == 0); |
| 144 |
exec @rpictA ; |
| 145 |
} |
| 146 |
# OK, we're running rtrace in some capacity... |
| 147 |
push @rtraceA, ('-n', "$nprocs"); |
| 148 |
die "Need single octree argument\n" if ($#ARGV != 0); |
| 149 |
my $oct = $ARGV[0]; |
| 150 |
my $view = `@vwrightA 0`; |
| 151 |
chomp $view; |
| 152 |
my @res = split(/\s/, `@vwraysA -d`); |
| 153 |
##################################################################### |
| 154 |
##### Resort pixels to reduce ambient cache collisions? |
| 155 |
if ($nprocs > 1 && $ambounce > 0 && $ambcache && defined($ambfile)) { |
| 156 |
if (!defined($outzbf) && !defined($outdir)) { |
| 157 |
# Straight picture output, so just shuffle sample order |
| 158 |
system "cnt -s $res[1] $res[3] > /tmp/ord$$.txt"; |
| 159 |
die "cnt error\n" if ( $? ); |
| 160 |
system "@vwraysA -ff -i < /tmp/ord$$.txt " . |
| 161 |
"| @rtraceA -ffa -ov '$oct' > /tmp/pix$$.txt"; |
| 162 |
die "Error running rtrace\n" if ( $? ); |
| 163 |
system "( getinfo < /tmp/pix$$.txt | getinfo -a 'VIEW=$view'; " . |
| 164 |
"getinfo - < /tmp/pix$$.txt | rlam /tmp/ord$$.txt - " . |
| 165 |
"| sort -k2rn -k1n ) | pvalue -r -Y $res[3] +X $res[1]"; |
| 166 |
die "rlam error\n" if ( $? ); |
| 167 |
unlink ("/tmp/ord$$.txt", "/tmp/pix$$.txt"); |
| 168 |
exit 0; |
| 169 |
} |
| 170 |
# Else randomize overture calculation to prime ambient cache |
| 171 |
my @ores = (int($res[1]/6), int($res[3]/6)); |
| 172 |
print STDERR "Running $ores[0] by $ores[1] overture calculation " . |
| 173 |
"to populate '$ambfile'...\n"; |
| 174 |
system "cnt -s @ores | @vwraysA -i -ff -x $ores[0] -y $ores[1] -pj 0 " . |
| 175 |
"| @rtraceA -ff -ov '$oct' > /dev/null"; |
| 176 |
die "Failure running overture\n" if ( $? ); |
| 177 |
print STDERR "Finished overture.\n"; |
| 178 |
} |
| 179 |
##################################################################### |
| 180 |
##### Generating picture with depth buffer? |
| 181 |
if (defined $outzbf) { |
| 182 |
exec "@vwraysA -ff | @rtraceA -fff -olv @res '$oct' | " . |
| 183 |
"rsplit -ih -iH -f -of '$outzbf' -oh -oH -of3 - | " . |
| 184 |
"pvalue -r -df | getinfo -a 'VIEW=$view'"; |
| 185 |
} |
| 186 |
##################################################################### |
| 187 |
##### Base case with output picture only? |
| 188 |
if (! defined $outdir) { |
| 189 |
exec "@vwraysA -ff | @rtraceA -ffc @res '$oct' | getinfo -a 'VIEW=$view'"; |
| 190 |
} |
| 191 |
##################################################################### |
| 192 |
##### Layered image output case |
| 193 |
my @rsplitA = ("rsplit", "'-t '", "-ih", "-iH", "-oh", "-oH"); |
| 194 |
# Supported rtrace -o* options and output file name.typ |
| 195 |
my %rtoutC = ( |
| 196 |
v => 'radiance.hdr', |
| 197 |
r => 'r_refl.hdr', |
| 198 |
x => 'r_unrefl.hdr', |
| 199 |
l => 'd_effective.dpt', |
| 200 |
L => 'd_firstsurf.dpt', |
| 201 |
R => 'd_refl.dpt', |
| 202 |
X => 'd_unrefl.dpt', |
| 203 |
n => 'perturbed.nrm', |
| 204 |
N => 'unperturbed.nrm', |
| 205 |
s => 'surface.idx', |
| 206 |
m => 'modifier.idx', |
| 207 |
M => 'material.idx' |
| 208 |
); |
| 209 |
# Arguments for rsplit based on output file type |
| 210 |
my %rcodeC = ( |
| 211 |
'.hdr', ['-of3', '!pvalue -r -df -u'], |
| 212 |
'.dpt', ['-of', "!rcode_depth$refDepth -ff"], |
| 213 |
'.nrm', ['-of3', '!rcode_norm -ff'], |
| 214 |
'.idx', ['-oa', '!rcode_ident "-t "'] |
| 215 |
); |
| 216 |
if ($irrad) { # adjust actions for -i+ option |
| 217 |
$rtoutC{'v'} = 'irradiance.hdr'; |
| 218 |
delete $rtoutC{'r'}; |
| 219 |
delete $rtoutC{'x'}; |
| 220 |
delete $rtoutC{'R'}; |
| 221 |
delete $rtoutC{'X'}; |
| 222 |
} |
| 223 |
if (! -d $outdir) { |
| 224 |
mkdir $outdir or die("Cannot create output directory '$outdir'\n"); |
| 225 |
} |
| 226 |
# construct rsplit command |
| 227 |
foreach my $oval (split //, $outlyr) { |
| 228 |
die "Duplicate or unsupported type '$oval' in -o$outlyr\n" |
| 229 |
if (!defined $rtoutC{$oval}); |
| 230 |
my $outfile = "$outdir/$rtoutC{$oval}"; |
| 231 |
die "File '$outfile' already exists\n" if (-e $outfile); |
| 232 |
my ($otyp) = ($rtoutC{$oval} =~ /(\.[^.]+)$/); |
| 233 |
push @rsplitA, $rcodeC{$otyp}[0]; |
| 234 |
push @rsplitA, qq{'$rcodeC{$otyp}[1] > "$outfile"'}; |
| 235 |
delete $rtoutC{$oval}; |
| 236 |
} |
| 237 |
# call rtrace + rsplit |
| 238 |
exec "@vwraysA -ff | @rtraceA -fff @res '$oct' | getinfo -a 'VIEW=$view' | @rsplitA"; |
