[ViewVC] Annotation of: radiance/ray/src/rt/SConscript

from __future__ import division, print_function, unicode_literals

import os
from build_utils import vstamp

Import('env') # inherit from parent

mlib = env['RAD_MLIB']

# compose paths
def radbin(name): return os.path.join(env['RAD_BUILDBIN'], name)
def radlib(name): return os.path.join(env['RAD_BUILDLIB'], name)

# custom compile flags
dielectric = env.Object(source='dielectric.c',
                CCFLAGS=env.get('CCFLAGS',[]) + ['-DDISPERSE'])

duphead = env.Object(source="duphead.c")
persist = env.Object(source="persist.c")
ambio = env.Object(source="ambio.c")
rayfifo = env.Object(source="rayfifo.c")
raypwin = env.Object(source="raypwin.c")
raycalls = env.Object(source="raycalls.c")
pmaptype = env.Object(source="pmaptype.c")
pmapparm = env.Object(source="pmapparm.c")


# source and object dependencies
RAY = Split('''ambcomp.c ambient.c freeobjmem.c initotypes.c preload.c
                raytrace.c renderopts.c''') + [ambio]
PMAP = Split('''pmap.c pmapsrc.c pmapmat.c pmaprand.c pmapio.c pmapdata.c
        pmapbias.c pmapcontrib.c pmapamb.c pmapray.c pmapopt.c pmapdiag.c
                oocbuild.c ooccache.c oocnn.c oocmorton.c oococt.c oocsort.c
                pmcontrib2.c pmapkdt.c pmutil.c
                ''') + [pmaptype, pmapparm]
# not ready yet: pmapooc.c 
SURF = Split('''srcsamp.c srcsupp.c srcobstr.c source.c virtuals.c sphere.c
                o_face.c o_cone.c o_instance.c o_mesh.c''')
MAT = Split('''aniso.c normal.c m_clip.c glass.c m_brdf.c m_mirror.c
                m_direct.c m_mist.c fprism.c m_alias.c m_bsdf.c ashikhmin.c '''
                ) + [dielectric]
MOD = Split('p_func.c t_func.c p_data.c t_data.c text.c mx_func.c mx_data.c')
SUP = Split('func.c noise3.c data.c')

# build libraries
rsrc = RAY + PMAP + SURF + MAT + MOD + SUP
env.Command('Version.c', 'VERSION', vstamp.build_version_c)
env.Depends('Version.c', rsrc)
Version = env.Object(source=['Version.c'])
env.version = Version # make it remotely accessible
tracelib = env.Library(target=radlib('rttrace'), source=rsrc + [Version])

rclib = env.Library(target=radlib('raycalls'),
                source=Split('raycalls.c $RAD_PCALLS'))
Default(rclib)

rtmain = env.Object(source=['rtmain.c'],
                CCFLAGS=env.get('CCFLAGS',[]) + ['-DNICE=4'])

# build executables
PROGS = [
('mkpmap',   ['mkpmap.c', Version],
         ['rttrace', 'rtrad', '$RAD_SOCKETLIB', mlib]),
('pmapdump', ['pmapdump.c', pmaptype, pmapparm, Version],
         ['rtrad', '$RAD_SOCKETLIB', mlib]),
('lookamb',  ['lookamb.c', ambio], ['rtrad', mlib]),
('rcontrib', Split('rcmain.c rcontrib.c rc2.c rc3.c') + [Version],
         ['rttrace', 'rtrad', '$RAD_SOCKETLIB', mlib]),
('rtrace',   ['rtrace.c', duphead, persist, rtmain, rayfifo, raypwin, raycalls],
         ['rttrace', 'rtrad'] +  mlib),
('rpict',    Split('rpmain.c rpict.c srcdraw.c') + [duphead, persist],
         ['rttrace', 'rtrad', '$RAD_SOCKETLIB']+mlib),
]
for p in PROGS:
        prog = env.Program(target=radbin(p[0]), source = p[1], LIBS = p[2]),
        Default(prog)
        env.Append(RAD_BININSTALL=[env.Install('$RAD_BINDIR', prog)])

# we need RVOBJS for any derived viewers, such as winrview
if os.name == 'nt': RV_DEF = ['WIN_RVIEW']
else: RV_DEF = []
rvmain = env.Object(source='rvmain.c',
                CCFLAGS=env['CCFLAGS'] + ['-DNICE=6'])
rvobjs = [rvmain]
for src in  Split('''rview.c rv2.c rv3.c
        devtable.c devcomm.c colortab.c editline.c'''):
        rvobjs.append(env.Object(source=src,
                        CPPDEFINES=env.get('CPPDEFINES', []) + RV_DEF))
env['RVOBJS'] = rvobjs

if env.has_key('X11LIB'): # lots of special requirements for rvu
        x11incls = [env['X11INCLUDE']] + env['CPPPATH']
        x11 = env.Object(source='x11.c', CPPPATH=x11incls)
        x11twind = env.Object(source='x11twind.c', CPPPATH=x11incls)
        rvxobjs = [x11, x11twind]
        rvsrc =  rvobjs + rvxobjs
        rvu = env.Program(target=radbin('rvu'), source=rvsrc,
                LIBPATH=env['LIBPATH'] + [env['X11LIB']],
                LIBS = ([rclib, 'rttrace', 'rtrad', 'X11'] + mlib)
                )
        Default(rvu)
        env.Append(RAD_BININSTALL=[env.Install('$RAD_BINDIR', rvu)])

LIBFILES = Split('rayinit.cal')
env.Append(RAD_RLIBINSTALL=[env.Install('$RAD_RLIBDIR', LIBFILES)])

# vim: set syntax=python:
# vi: set ts=4 sw=4 :
Revision:	1.19
Committed:	Mon Jan 8 13:38:37 2018 UTC (6 years, 4 months ago) by schorsch
Branch:	MAIN
Changes since 1.18:	+8 -2 lines
Log Message:	Updating to SCons 3.x, adding support for Python 3
#	User	Rev	Content
1	schorsch	1.19	from __future__ import division, print_function, unicode_literals
2
3	schorsch	1.1	import os
4	schorsch	1.5	from build_utils import vstamp
5	schorsch	1.1
6			Import('env') # inherit from parent
7
8	schorsch	1.2	mlib = env['RAD_MLIB']
9	schorsch	1.1
10			# compose paths
11	schorsch	1.2	def radbin(name): return os.path.join(env['RAD_BUILDBIN'], name)
12			def radlib(name): return os.path.join(env['RAD_BUILDLIB'], name)
13	schorsch	1.1
14			# custom compile flags
15	schorsch	1.2	dielectric = env.Object(source='dielectric.c',
16			CCFLAGS=env.get('CCFLAGS',[]) + ['-DDISPERSE'])
17
18			duphead = env.Object(source="duphead.c")
19			persist = env.Object(source="persist.c")
20			ambio = env.Object(source="ambio.c")
21	greg	1.12	rayfifo = env.Object(source="rayfifo.c")
22			raypwin = env.Object(source="raypwin.c")
23	greg	1.13	raycalls = env.Object(source="raycalls.c")
24	schorsch	1.16	pmaptype = env.Object(source="pmaptype.c")
25			pmapparm = env.Object(source="pmapparm.c")
26	schorsch	1.2
27	schorsch	1.1
28			# source and object dependencies
29	schorsch	1.2	RAY = Split('''ambcomp.c ambient.c freeobjmem.c initotypes.c preload.c
30	schorsch	1.5	raytrace.c renderopts.c''') + [ambio]
31	schorsch	1.15	PMAP = Split('''pmap.c pmapsrc.c pmapmat.c pmaprand.c pmapio.c pmapdata.c
32	schorsch	1.19	pmapbias.c pmapcontrib.c pmapamb.c pmapray.c pmapopt.c pmapdiag.c
33			oocbuild.c ooccache.c oocnn.c oocmorton.c oococt.c oocsort.c
34			pmcontrib2.c pmapkdt.c pmutil.c
35			''') + [pmaptype, pmapparm]
36			# not ready yet: pmapooc.c
37	schorsch	1.3	SURF = Split('''srcsamp.c srcsupp.c srcobstr.c source.c virtuals.c sphere.c
38			o_face.c o_cone.c o_instance.c o_mesh.c''')
39	schorsch	1.1	MAT = Split('''aniso.c normal.c m_clip.c glass.c m_brdf.c m_mirror.c
40	schorsch	1.15	m_direct.c m_mist.c fprism.c m_alias.c m_bsdf.c ashikhmin.c '''
41			) + [dielectric]
42	schorsch	1.1	MOD = Split('p_func.c t_func.c p_data.c t_data.c text.c mx_func.c mx_data.c')
43			SUP = Split('func.c noise3.c data.c')
44
45			# build libraries
46	schorsch	1.15	rsrc = RAY + PMAP + SURF + MAT + MOD + SUP
47	schorsch	1.5	env.Command('Version.c', 'VERSION', vstamp.build_version_c)
48			env.Depends('Version.c', rsrc)
49	schorsch	1.6	Version = env.Object(source=['Version.c'])
50	schorsch	1.16	env.version = Version # make it remotely accessible
51	schorsch	1.18	tracelib = env.Library(target=radlib('rttrace'), source=rsrc + [Version])
52	schorsch	1.1
53	schorsch	1.17	rclib = env.Library(target=radlib('raycalls'),
54			source=Split('raycalls.c $RAD_PCALLS'))
55	schorsch	1.1	Default(rclib)
56
57	schorsch	1.17	rtmain = env.Object(source=['rtmain.c'],
58			CCFLAGS=env.get('CCFLAGS',[]) + ['-DNICE=4'])
59
60	schorsch	1.1	# build executables
61	schorsch	1.17	PROGS = [
62			('mkpmap', ['mkpmap.c', Version],
63			['rttrace', 'rtrad', '$RAD_SOCKETLIB', mlib]),
64			('pmapdump', ['pmapdump.c', pmaptype, pmapparm, Version],
65			['rtrad', '$RAD_SOCKETLIB', mlib]),
66			('lookamb', ['lookamb.c', ambio], ['rtrad', mlib]),
67			('rcontrib', Split('rcmain.c rcontrib.c rc2.c rc3.c') + [Version],
68			['rttrace', 'rtrad', '$RAD_SOCKETLIB', mlib]),
69			('rtrace', ['rtrace.c', duphead, persist, rtmain, rayfifo, raypwin, raycalls],
70			['rttrace', 'rtrad'] + mlib),
71			('rpict', Split('rpmain.c rpict.c srcdraw.c') + [duphead, persist],
72			['rttrace', 'rtrad', '$RAD_SOCKETLIB']+mlib),
73			]
74			for p in PROGS:
75			prog = env.Program(target=radbin(p[0]), source = p[1], LIBS = p[2]),
76			Default(prog)
77			env.Append(RAD_BININSTALL=[env.Install('$RAD_BINDIR', prog)])
78	schorsch	1.15
79	schorsch	1.18	# we need RVOBJS for any derived viewers, such as winrview
80			if os.name == 'nt': RV_DEF = ['WIN_RVIEW']
81			else: RV_DEF = []
82			rvmain = env.Object(source='rvmain.c',
83			CCFLAGS=env['CCFLAGS'] + ['-DNICE=6'])
84			rvobjs = [rvmain]
85			for src in Split('''rview.c rv2.c rv3.c
86			devtable.c devcomm.c colortab.c editline.c'''):
87			rvobjs.append(env.Object(source=src,
88			CPPDEFINES=env.get('CPPDEFINES', []) + RV_DEF))
89			env['RVOBJS'] = rvobjs
90	schorsch	1.2
91	schorsch	1.4	if env.has_key('X11LIB'): # lots of special requirements for rvu
92	schorsch	1.2	x11incls = [env['X11INCLUDE']] + env['CPPPATH']
93			x11 = env.Object(source='x11.c', CPPPATH=x11incls)
94			x11twind = env.Object(source='x11twind.c', CPPPATH=x11incls)
95	schorsch	1.18	rvxobjs = [x11, x11twind]
96			rvsrc = rvobjs + rvxobjs
97	schorsch	1.4	rvu = env.Program(target=radbin('rvu'), source=rvsrc,
98	schorsch	1.2	LIBPATH=env['LIBPATH'] + [env['X11LIB']],
99	schorsch	1.17	LIBS = ([rclib, 'rttrace', 'rtrad', 'X11'] + mlib)
100	schorsch	1.11	)
101	schorsch	1.4	Default(rvu)
102	schorsch	1.6	env.Append(RAD_BININSTALL=[env.Install('$RAD_BINDIR', rvu)])
103	schorsch	1.1
104			LIBFILES = Split('rayinit.cal')
105	schorsch	1.6	env.Append(RAD_RLIBINSTALL=[env.Install('$RAD_RLIBDIR', LIBFILES)])
106	schorsch	1.1
107	schorsch	1.16	# vim: set syntax=python:
108	schorsch	1.19	# vi: set ts=4 sw=4 :